PK       ! rZ�_�  �    Types.pmnu �[���        # Copyright © 2007 Frank Lichtenheld <djpig@debian.org>
# Copyright © 2010, 2013-2016 Guillem Jover <guillem@debian.org>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.

package Dpkg::Build::Types;

use strict;
use warnings;

our $VERSION = '0.02';
our @EXPORT = qw(
    BUILD_DEFAULT
    BUILD_SOURCE
    BUILD_ARCH_DEP
    BUILD_ARCH_INDEP
    BUILD_BINARY
    BUILD_FULL
    build_has_any
    build_has_all
    build_has_none
    build_is
    set_build_type
    set_build_type_from_options
    set_build_type_from_targets
    get_build_options_from_type
);

use Exporter qw(import);

use Dpkg::Gettext;
use Dpkg::ErrorHandling;

=encoding utf8

=head1 NAME

Dpkg::Build::Types - track build types

=head1 DESCRIPTION

The Dpkg::Build::Types module is used by various tools to track and decide
what artifacts need to be built.

The build types are bit constants that are exported by default. Multiple
types can be ORed.

=head1 CONSTANTS

=over 4

=item BUILD_DEFAULT

This build is the default.

=item BUILD_SOURCE

This build includes source artifacts.

=item BUILD_ARCH_DEP

This build includes architecture dependent binary artifacts.

=item BUILD_ARCH_INDEP

This build includes architecture independent binary artifacts.

=item BUILD_BINARY

This build includes binary artifacts.

=item BUILD_FULL

This build includes source and binary artifacts.

=cut

# Simple types.
use constant {
    BUILD_DEFAULT      => 1,
    BUILD_SOURCE       => 2,
    BUILD_ARCH_DEP     => 4,
    BUILD_ARCH_INDEP   => 8,
};

# Composed types.
use constant BUILD_BINARY => BUILD_ARCH_DEP | BUILD_ARCH_INDEP;
use constant BUILD_FULL   => BUILD_BINARY | BUILD_SOURCE;

my $current_type = BUILD_FULL | BUILD_DEFAULT;
my $current_option = undef;

my @build_types = qw(full source binary any all);
my %build_types = (
    full => BUILD_FULL,
    source => BUILD_SOURCE,
    binary => BUILD_BINARY,
    any => BUILD_ARCH_DEP,
    all => BUILD_ARCH_INDEP,
);
my %build_targets = (
    'clean' => BUILD_SOURCE,
    'build' => BUILD_BINARY,
    'build-arch' => BUILD_ARCH_DEP,
    'build-indep' => BUILD_ARCH_INDEP,
    'binary' => BUILD_BINARY,
    'binary-arch' => BUILD_ARCH_DEP,
    'binary-indep' => BUILD_ARCH_INDEP,
);

=back

=head1 FUNCTIONS

=over 4

=item build_has_any($bits)

Return a boolean indicating whether the current build type has any of the
specified $bits.

=cut

sub build_has_any
{
    my ($bits) = @_;

    return $current_type & $bits;
}

=item build_has_all($bits)

Return a boolean indicating whether the current build type has all the
specified $bits.

=cut

sub build_has_all
{
    my ($bits) = @_;

    return ($current_type & $bits) == $bits;
}

=item build_has_none($bits)

Return a boolean indicating whether the current build type has none of the
specified $bits.

=cut

sub build_has_none
{
    my ($bits) = @_;

    return !($current_type & $bits);
}

=item build_is($bits)

Return a boolean indicating whether the current build type is the specified
set of $bits.

=cut

sub build_is
{
    my ($bits) = @_;

    return $current_type == $bits;
}

=item set_build_type($build_type, $build_option, %opts)

Set the current build type to $build_type, which was specified via the
$build_option command-line option.

The function will check and abort on incompatible build type assignments,
this behavior can be disabled by using the boolean option "nocheck".

=cut

sub set_build_type
{
    my ($build_type, $build_option, %opts) = @_;

    usageerr(g_('cannot combine %s and %s'), $current_option, $build_option)
        if not $opts{nocheck} and
           build_has_none(BUILD_DEFAULT) and $current_type != $build_type;

    $current_type = $build_type;
    $current_option = $build_option;
}

=item set_build_type_from_options($build_types, $build_option, %opts)

Set the current build type from a list of comma-separated build type
components.

The function will check and abort on incompatible build type assignments,
this behavior can be disabled by using the boolean option "nocheck".

=cut

sub set_build_type_from_options
{
    my ($build_parts, $build_option, %opts) = @_;

    my $build_type = 0;
    foreach my $type (split /,/, $build_parts) {
        usageerr(g_('unknown build type %s'), $type)
            unless exists $build_types{$type};
        $build_type |= $build_types{$type};
    }

    set_build_type($build_type, $build_option, %opts);
}

=item set_build_type_from_targets($build_targets, $build_option, %opts)

Set the current build type from a list of comma-separated build target
components.

The function will check and abort on incompatible build type assignments,
this behavior can be disabled by using the boolean option "nocheck".

=cut

sub set_build_type_from_targets
{
    my ($build_targets, $build_option, %opts) = @_;

    my $build_type = 0;
    foreach my $target (split /,/, $build_targets) {
        $build_type |= $build_targets{$target} // BUILD_BINARY;
    }

    set_build_type($build_type, $build_option, %opts);
}

=item get_build_options_from_type()

Get the current build type as a set of comma-separated string options.

=cut

sub get_build_options_from_type
{
    my $local_type = $current_type;

    my @parts;
    foreach my $type (@build_types) {
        my $part_bits = $build_types{$type};
        if (($local_type & $part_bits) == $part_bits) {
            push @parts, $type;
            $local_type &= ~$part_bits;
        }
    }

    return join ',', @parts;
}

=back

=head1 CHANGES

=head2 Version 0.xx

This is a private module.

=cut

1;
PK       ! Ϋtӎ  �    Info.pmnu �[���        # Copyright © 2016 Guillem Jover <guillem@debian.org>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.

package Dpkg::Build::Info;

use strict;
use warnings;

our $VERSION = '1.01';
our @EXPORT_OK = qw(
    get_build_env_whitelist
    get_build_env_allowed
);

use Exporter qw(import);

=encoding utf8

=head1 NAME

Dpkg::Build::Info - handle build information

=head1 DESCRIPTION

The Dpkg::Build::Info module provides functions to handle the build
information.

=head1 FUNCTIONS

=over 4

=item @envvars = get_build_env_allowed()

Get an array with the allowed list of environment variables that can affect
the build, but are still not privacy revealing.

=cut

my @env_allowed = (
    # Toolchain.
    qw(CC CPP CXX OBJC OBJCXX PC FC M2C AS LD AR RANLIB MAKE AWK LEX YACC),
    # Toolchain flags.
    qw(ASFLAGS CFLAGS CPPFLAGS CXXFLAGS OBJCFLAGS OBJCXXFLAGS GCJFLAGS DFLAGS
       FFLAGS LDFLAGS ARFLAGS MAKEFLAGS),
    # Dynamic linker, see ld(1).
    qw(LD_LIBRARY_PATH),
    # Locale, see locale(1).
    qw(LANG LC_ALL LC_CTYPE LC_NUMERIC LC_TIME LC_COLLATE LC_MONETARY
       LC_MESSAGES LC_PAPER LC_NAME LC_ADDRESS LC_TELEPHONE LC_MEASUREMENT
       LC_IDENTIFICATION),
    # Build flags, see dpkg-buildpackage(1).
    qw(DEB_BUILD_OPTIONS DEB_BUILD_PROFILES),
    # DEB_flag_{SET,STRIP,APPEND,PREPEND} will be recorded after being merged
    # with system config and user config.
    # See deb-vendor(1).
    qw(DEB_VENDOR),
    # See dpkg(1).
    qw(DPKG_ROOT DPKG_ADMINDIR),
    # See dpkg-architecture(1).
    qw(DPKG_DATADIR),
    # See Dpkg::Vendor(3).
    qw(DPKG_ORIGINS_DIR),
    # See dpkg-gensymbols(1).
    qw(DPKG_GENSYMBOLS_CHECK_LEVEL),
    # See <https://reproducible-builds.org/specs/source-date-epoch>.
    qw(SOURCE_DATE_EPOCH),
);

sub get_build_env_allowed {
    return @env_allowed;
}

=item @envvars = get_build_env_whitelist()

This is a deprecated alias for get_build_env_allowed().

=cut

sub get_build_env_whitelist {
    warnings::warnif('deprecated',
        'Dpkg::Build::Info::get_build_env_whitelist() is deprecated, ' .
        'use get_build_env_allowed() instead');
    return get_build_env_allowed();
}

=back

=head1 CHANGES

=head2 Version 1.01 (dpkg 1.20.1)

New function: get_build_env_allowed().

Deprecated function: get_build_env_whitelist().

=head2 Version 1.00 (dpkg 1.18.14)

Mark the module as public.

=cut

1;
PK       ! ,�  �    Env.pmnu �[���        # Copyright © 2012 Guillem Jover <guillem@debian.org>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <https://www.gnu.org/licenses/>.

package Dpkg::Build::Env;

use strict;
use warnings;

our $VERSION = '0.01';

my %env_modified = ();
my %env_accessed = ();

=encoding utf8

=head1 NAME

Dpkg::Build::Env - track build environment

=head1 DESCRIPTION

The Dpkg::Build::Env module is used by dpkg-buildflags to track the build
environment variables being used and modified.

=head1 FUNCTIONS

=over 4

=item set($varname, $value)

Update the build environment variable $varname with value $value. Record
it as being accessed and modified.

=cut

sub set {
    my ($varname, $value) = @_;
    $env_modified{$varname} = 1;
    $env_accessed{$varname} = 1;
    $ENV{$varname} = $value;
}

=item get($varname)

Get the build environment variable $varname value. Record it as being
accessed.

=cut

sub get {
    my $varname = shift;
    $env_accessed{$varname} = 1;
    return $ENV{$varname};
}

=item has($varname)

Return a boolean indicating whether the environment variable exists.
Record it as being accessed.

=cut

sub has {
    my $varname = shift;
    $env_accessed{$varname} = 1;
    return exists $ENV{$varname};
}

=item @list = list_accessed()

Returns a list of all environment variables that have been accessed.

=cut

sub list_accessed {
    my @list = sort keys %env_accessed;
    return @list;
}

=item @list = list_modified()

Returns a list of all environment variables that have been modified.

=cut

sub list_modified {
    my @list = sort keys %env_modified;
    return @list;
}

=back

=head1 CHANGES

=head2 Version 0.xx

This is a private module.

=cut

1;
PK         ! rZ�_�  �                  Types.pmnu �[���        PK         ! Ϋtӎ  �                Info.pmnu �[���        PK         ! ,�  �              �#  Env.pmnu �[���        PK      �   �, 